***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 14, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJA3403   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -1.213		 kp = 15		)
.model  dds   d(
+   is = 1.000e-10	  n = 1.450		   rs = 5.000e-2
+   eg = 1.182	       trs1 = -1.200e-3)
.model  dbody d(
+   is = 1.000e-10	  n = 1.450		   rs = 5.000e-2
+   eg = 1.182	       trs1 = -1.200e-3
+  cjo = 6.737e-11	  m = 3.571e-1		   vj = 1.389e-1
+   bv = 33		ibv = 250e-6
+ tbv1 = 9.006e-4	tbv2 = -1.350e-6	   tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd    d(
+  cjo = 2.389e-10	  m = 6.398e-1		   vj = 3.361e-1)
.param
+  cgs = 6.447e-10	cgd = 2.307e-10
+   rd = 3.417e-2	 ra = 3.417e-2
+ trd1 = 6.500e-3	trd2 = 1.500e-5
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  3  2t   table   {v(S, 1t)}
+((0.00 , 0.00 ),
+ (0.50 , 0.45 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.50 ),
+ (1.75 , 1.75 ),
+ (2.00 , 2.05 ),
+ (2.25 , 2.29 ),
+ (2.50 , 2.46 ),
+ (2.75 , 2.60 ),
+ (3.00 , 2.80 ),
+ (4.00 , 3.50 ),
+ (4.50 , 3.80 ),
+ (10.0 , 7.00 ),
+ (12.0 , 8.00 ),
+ (14.0 , 8.00 ))
egt	  1  2t   value = {5e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1},{trd2}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1     1t   8   6   6   inter
e1      8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd    7   4   10meg
dgd     4   6   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends
*$
